sht11

[kemalsa]

ya beyler şu sht11 basic komutlarıyla nasıl surebiliriz bikac denemem oldu yapamadım turkengineers in sitesinde derlenmiş var.

[kesmez]

http://www.melabs.com/resources/index.htm
sayfasında

Search the PicBasic List for answers.

tıkla çıkan sayfada sht11 için arama yaptır bi sürü çıkıyor...

[kemalsa]

birkactane buldum denicem inşalah olur şimdiden cok teşekürler

[mmengi]

arkadaşlar sht11 için pbp codları arıyorum.turkengineers taki cod düzgün çalışmıyor. kemalsa dostum bir sonuca ulaşabildin mi?

[kemalsa]

'****************************************************************
'* Name : I2Ctemp.BAS *
'* Date : 04/27/2002 *
'* Notes : 16F84A, 4 Mhz crystal *
'* Notes : Read Temp & Humidity using Sensirion *
'* Notes : Sensor SHT11 *
'* Notes : Display on 2 line 20 character LCD *
'* Words : 452 *
'****************************************************************

SDA VAR PortB.0 ' Data pin
SCL VAR PortB.1 ' Clock pin

Temp VAR WORD ' Temperature data variable
Hum VAR WORD ' Humidity data variable

Pause 250 ' Allow LCD and sensor to initialize
LCDOut $FE, 1 ' Clear the screen
LCDOut $FE, $40,14,10,14,0,0,0,0,0 ' Create degree symbol in CGRAM
location 0
I2CWrite SDA, SCL, $0F ' Software reset SHT11
Pause 20 ' Wait 11mS after reset, before next
command

loop:
I2CRead SDA, SCL, $01, [Temp] ' Read temp from sensor
LCDOut $FE, $80, "Temp ", DEC Temp, " ", 0, "F " ' Display Temp
on line 1
Pause 100 ' Pause before next read

I2CRead SDA, SCL, $02, [Hum] ' Read Humidity from sensor
LCDOut $FE, $C0, "Humidity ", DEC Hum, " % " ' Display
Humidity on line 2
Pause 100 ' Pause before next read

GOTO loop ' Do it forever, I Hope

END ' Hope you never get here



veeeee
DEFINE LCD_DREG PORTC ' LCD data port C....
DEFINE LCD_DBIT 4 ' ....Bits 4-7
DEFINE LCD_RSREG PORTC ' Register Select pin Port C....
DEFINE LCD_RSBIT 1 ' ....Bit 1
DEFINE LCD_EREG PORTC ' Enable pin Port C....
DEFINE LCD_EBIT 2 ' ....Bit 2

DEFINE I2C_HOLD 1 ' Allow Slave device to hold SCL LOW

ADCON1 = 7 ' Set Port A to Digital
SDA VAR PortA.4 ' Data pin
SCL VAR PortB.0 ' Clock pin

tempM VAR WORD ' Temperature MSB
tempL VAR WORD ' Temperature LSB

Pause 200 ' Allow I2C Sensor to settle

LCDOut $FE, $40,14,10,14,0,0,0,0,0 ' Create degree symbol in CGRAM

I2CWrite SDA, SCL, $1E ' Software reset SHT11
pause 100

loop:
I2CRead SDA, SCL, $03, [tempM, tempL, crc]
LCDOut $FE, $80, "Temp ", DEC tempL , " ", DEC tempM, " " ' Display
LCDOut $FE, $8E, 0,"F" ' Display Degree symbol and F
GOTO loop ' Do it forever, I Hope

END ' Hope you never get here

bunları buldum ama hiç deneyemedim mantıklı gibi gözüküyor bir dene istersen..

[mmengi]

dostum verdiğin code lardan bir tanesini uygulamıştım ama lcd ekranda anlamsız rakamlar yazıyordu. verdiğin kodları tekrar deneyeceğim sonucu yazarım.

iyi çalışmalar.

[mmengi]

dostum üzgünüm ama bu programlar çalışmıyor ekranda 257 den başka bir şey okunmuyor. C de yazılmış kodlarını buldum onları basic olarak düzenlemeye çalışacağım. yinede teşekkürler.

iyi çalışmalar.

[mmengi]

arkadaşlar sonunda SHT11 i düzgün olarak LCD üzerinde çalıştırmayı başardım ustanın biri sağolsun ASM da güzel bir code yazmış.tek problem lcd  en az 22 karakterlik olması. Bir parça ASM bilgimle yazıları kısaltarak 16 karakterlik lcd ye sığdırdım. Üstatlardan ricam bunu 2X16 satıra nasıl dönüştürürüz. dosyaları aşağıdaki adreste bulabilirsiniz. birde bağlantı şemasını proteus da çizdim oradaki SHT11 semboliktir. hex dosyalar 16f876 ya göre hazırlanmıştır.

http://briefcase.yahoo.com/picprojep
(Usta byka inşallah kızmaz burayı kullandım diye)
ID:picprojep
PASS:18f458

[BabyBird]

üst satırda ve alt satırda tam olarak ne yazdırmak istiyorsun

[mmengi]

dostum orjinal kod 24x1 lcd için düşünülmüş.2x16 lcd de üstte temp altta humudity göstermek istiyordum. bugün biraz kafayı yorup lcd komutlarını inceledim 2x16 ya dönüştürdüm. aynı adreste bulabilirsiniz. ilgin için çok sağol.

kolay gelsin.

[elektromer]

Tüm arkadaşlara Selamlar..

mmengi  arkadaşim,

http://briefcase.yahoo.com/picprojep

ID:picprojep
PASS:18f458[/quote]

Yukarida verdigin adrese ID ve PASS ile girdim.
dosyaları isim olarak gordum ama download edemedim.

Kodları bu foruma mesaj olarak yazabilirmisin?

Veya mail adresime gönderebilirmisin?

[XNHCX]

 SHT11LCD.ASM  Kodları aşağıda...

;---------------------------------------------------------------
;Program to read data from SHT sensor, convert it and
;   dispaly on the LCD
;      claudiu.chiculita@ugal.ro
;      http://www.ac.ugal.ro/staff/ckiku/software
;
; Sensor is connected to pins 3,4 of PORTC
; LCD data (4..7) connected to (0..3) of PORTA
;---------------------------------------------------------------
;
;ConnectionReset
;TransmissionStart
;SHT_WriteByte
;WaitForData
;SHT_ReadByte
;AddCRC1byte, ReverseByte         - used to compute CRC
;SHT_ReadStatus, SHT_WriteStatus     - not implemented
;
;LinearizeHumidity               - 3xLinear, my method
;BCD8_100                     - used to convert % Humidity
;ComputeAsciiTemp               - convert Temperature
;InitLCD, InitTXT, ErrTXT         - LCD dispaly



   LIST      P=16F876A, F=INHX8M   ; list directive to define processor
   #include "p16f876a.inc"         ; processor specific variable definitions
   __CONFIG  _HS_OSC & _CP_OFF & _WDT_OFF & _BODEN_ON & _PWRTE_ON & _LVP_OFF & _DEBUG_OFF & _CPD_OFF
   
   radix dec
   errorlevel -302, -305
xtal EQU 20000000

   CBLOCK 0x20
   cnt1
   cnt2
   cnt3         ;cnt1/2/3 for delay
   al
   ah            ;ah/al used in crc compuations
   crc            ;computed crc so far
   byte         ;used in send/rcv
   info1
   info2
   infocrc         ;info1/2/crc  store the values received
   contor         ;cycle bits
   i
   thebyte, rwbyte
   SHT_reg_image   ;image of SHT11 status reg
   humip128,humip32
   txtTemp:5
   t100,t10,t1,tdot,t01
   txtHumi:9
   bcd100,bcd10,bcd1
   txtDewP
   
   hi,lo,shi,slo,digit   ; convet temp
   negative
   ENDC
   
;pin assignments:
#define   DATApin  PORTC,4   ;PORTC,4
#define   CLKpin   PORTC,3   ;PORTC,3

                           ;adr  command  r/w
#define STATUS_REG_W 0x06   ;000   0011    0
#define STATUS_REG_R 0x07   ;000   0011    1
#define MEASURE_TEMP 0x03   ;000   0001    1
#define MEASURE_HUMI 0x05   ;000   0010    1
#define RESET_SHT    0x1e   ;000   1111    0

BANK0_   macro         ;BANK1 -> BANK0
      bcf      STATUS,RP0
      endm
BANK1_   macro         ;BANK0 -> BANK1
      bsf      STATUS,RP0
      endm

tmic   macro
      goto   $+1
      endm
; at high frequency xtals and *very* long wires to the sensor
; you may wish to add a small delay (several instructions)
; at the end of SDAT and SCLK macros
; also the pull-up resistor should be smaller
SDAT   macro updown
      if updown==0
         bcf      DATApin
      else
         bsf      DATApin
      endif
      endm

SCLK   macro updown
      if updown==0
         bcf      CLKpin
      else
         bsf      CLKpin
      endif
      endm

MakeSDATinput   macro
      BANK1_
      bsf      DATApin      ;TRIS=1
      BANK0_
      endm

MakeSDAToutput macro
      BANK1_
      bcf      DATApin      ;TRIS=0
      BANK0_
      endm

DelayN   macro msx10
   movlw msx10
   call DelayMs
   endm

loadw   macro   arg1
   movlw   high(arg1)
   movwf   hi
   movlw   low(arg1)
   movwf   lo
   endm
loads   macro   arg1
   movlw   high(arg1)
   movwf   shi
   movlw   low(arg1)
   movwf   slo
   endm
dodigit   macro   arg1
   loads   arg1
   call   dosub
   endm


;ooooooooooooo RESET ooooooooooooooooooooooooo
   ORG       0x0000
   clrf   STATUS
   movlw   0x00
   movwf   PCLATH
   goto   init


;************ initial *******************
init
   clrf PORTA
   bsf     STATUS,RP0      ; select bank 1
   movlw   d'10'         ; at 20Mhz with 115200 => 10
   movwf   SPBRG         ; at  4Mhz with  19200 => 12
   movlw   b'00100100'      ; TXEN+BRGH
   movwf   TXSTA
   movlw 6
   movwf ADCON1
   clrf TRISA            ;all outputs
   movlw B'11111100'
   movwf TRISC
   ;
   bcf      CLKpin         ;TRIS=0    CLK=output
   ;
   bcf      STATUS,RP0      ; select bank 0
   movlw   b'10010000'
   movwf   RCSTA
   bcf      PORTC,0
   bcf      PORTC,1

   clrf   SHT_reg_image   ;Status register of SHT11 is initially 0
   call   InitLCD
   call   InitTXT
start
   movlw   5
   call SHT11_acquire
      addlw   0         ;check errors
      btfss   STATUS,Z
      goto   treatcommerr
   call   LinearizeHumidity
   movwf   byte
   call   BCD8_100
   
   movlw   3
   call SHT11_acquire
      addlw   0         ;check errors
      btfss   STATUS,Z
      goto   treatcommerr
   movf   info1,w
   movwf   hi
   movf   info2,w
   movwf   lo
   loads   4000
   clrf   negative
   call   Sub16
   bc      positive
   loads   1            ;take absolute value
   call   Sub16
   comf   hi
   comf   lo
   incf   negative
positive
   call   ComputeAsciiTemp
afisLCD
   
   movlw   0x02         ; home
   call   LCD_Cmd

   
      
   bsf      rwbyte,5
   movlw   12
   movwf   contor
   movlw   txtTemp-1
   movwf   FSR

   
incafis   
   incf   FSR
   movf   INDF,w
   call   LCD_Cmd
   decfsz   contor
   goto   incafis
   clrf   rwbyte
   



   movlw   0xC0         ; 2 Nd home
   call   LCD_Cmd

   
   bsf      rwbyte,5
   movlw   9
   movwf   contor
   movlw   txtTemp+13
   movwf   FSR

incafis1

   incf   FSR
   movf   INDF,w
   call   LCD_Cmd
   decfsz   contor
   goto   incafis1
   clrf   rwbyte










   movlw   0
   call   DelayMs
   movlw   0
   call   DelayMs
   goto   start

treatcommerr
   call   ErrTXT
   goto   afisLCD   

;************** PROCEDURES ****************************************   
SHT11_acquire
   ; expects in W the command to be sent 3/5
   movwf   byte
   MakeSDAToutput
   call   TransmissionStart
   tmic
      movf   SHT_reg_image,w
      movwf   crc         ;crc is initialised with Status Register = 0
   
      movf   byte,w
      call   AddCRC1byte   ;command also enters in crc sum
   call   SHT_WriteByte
      btfsc   STATUS,C      ; in case of error(ack not received)
      goto   ErrorNoACK     ; Send err
   call   WaitForData
      xorlw   1            ; 1=timeout
      btfsc   STATUS,Z      
      goto   ErrorTimeout   ;W=1
   call   SHT_ReadByte      ;H
      movwf   info1
      call   AddCRC1byte          
   call   SHT_ReadByte      ;L
      movwf   info2
      call   AddCRC1byte
   call   SHT_ReadByte      ;CRC
      movf   byte,w
      movwf   infocrc
      call   ReverseByte
      
   ;check CRC
      xorwf   crc
      btfss   STATUS,Z
      goto   ErrorCRCFailed
      
   ;Here we do whatever we want with the values: info1,info2
   retlw   0      ;OK

ErrorNoACK               ;treat errors
   movlw   253      
   goto   DoError
ErrorTimeout
   movlw   254      
   goto   DoError
ErrorCRCFailed
   movlw   255      
   goto   DoError
DoError
   ;call   SendW
   call   ConnectionReset
   retlw   255         ;error


;------------------------------------------------------------------
TransmissionStart
   SDAT 1
   ;SCLK  0   ;?default
   SCLK 1
   SDAT 0
   SCLK 0
   SCLK 1
   SDAT 1
   SCLK 0
   return


;----------------------------------------------------------------------------------
; writes a byte to the sensor
; -> SDAT must be output already (and the line should be in 1) as left from TransmissionStart
; -> At the end the SDAT will be left as input
; -> Carry=1 if no ACK was received
SHT_WriteByte
   movlw   8
   movwf   contor
altbitw
   SCLK 0            
   rlf      byte
   btfss   STATUS,C
   SDAT 0
   btfsc   STATUS,C
   SDAT 1
   SCLK 1
   decfsz   contor      
   goto   altbitw      
   
   SCLK 0            ; see NOTE(1)
   MakeSDATinput      ;
   SCLK 1
   bcf      STATUS,C
   btfsc   DATApin
   bsf      STATUS,C      ; signal error  Carry=1
   SCLK 0
   return
   

;//----------------------------------------------------------------------------------
;// reads a byte form the sensor
; -> Data from sensor must be now ready to read
; -> SDAT must be input already (and the line should be in zero)
; -> SCLK=0
; output => reading = byte = W
SHT_ReadByte
   movlw   8
   movwf   contor
altbitr
   SCLK 1
   bcf      STATUS,C      
   btfsc   DATApin      ;read line
   bsf   STATUS,C
   rlf      byte
   SCLK 0
   decfsz   contor
   goto   altbitr
   
   MakeSDAToutput
   SDAT 0            ;gives ACK
   SCLK 1
   SCLK 0
   MakeSDATinput
   
   movf   byte,w
   return
   
   
;--------------------------------------------
WaitForData            ; Timeout of 250ms
   movlw   4         ; =4 for xtal=20MHz
   movwf   cnt1
ddc1
   clrf   cnt2
ddc2   
   clrf   cnt3
ddc3
      btfss   DATApin   ;wait for data to go low
      retlw   0
   decfsz   cnt3
   goto   ddc3
   decfsz   cnt2
   goto   ddc2
   decfsz   cnt1
   goto   ddc1
   retlw   1         ;Timeout
   
   
;----------------------------------------------      
SendW
   btfss   PIR1,TXIF   ;empty?
   goto   SendW
   movwf   TXREG
   return
   
   
;----------------------------------------------      
;W=new byte            crc = crc # W
AddCRC1byte
   movwf   al
   movlw   8
   movwf   contor
abitcrc   
   movf   al,w
   xorwf   crc,w
   movwf   ah
   rlf      ah
   movlw   b'00011000'
   btfsc   STATUS,C
   xorwf   crc         
   rlf      crc
   rlf      al
   
   decfsz   contor
   goto   abitcrc
   return


;----------------------------------------------         
;W -> byte to be inverted
ReverseByte
   movwf   ah
   movlw   8
   movwf   contor
ivbi
   rlf      ah
   rrf      al
   decfsz   contor
   goto   ivbi
   movf   al,w
   return
   
   
;----------------------------------------------         
ConnectionReset
   SDAT 1
   SCLK 0
   movlw   9
   movwf   contor
crac
   SCLK 1
   SCLK 0   
   decfsz   contor
   goto   crac
   call   TransmissionStart
   return
   
;########################################################################3
InitLCD
   DelayN 50
   clrf   rwbyte
   movlw   3
   call   Raw1
   DelayN 5
   movlw   3
   call   Raw1
   DelayN 1
   movlw   3
   call   Raw1
   DelayN 1
   movlw   2
   call   Raw1
   DelayN 1
   
   

   movlw   0x28      
   call   LCD_Cmd
   movlw   0x08      ; off
   call   LCD_Cmd
   movlw   0x01      ; clr
   call   LCD_Cmd
   movlw   0x0c      ; on:   1 on curs blink
   call   LCD_Cmd
   movlw   0x06      ; mode: 0  1  inc shift
   call   LCD_Cmd
   
   DelayN 10
   return

Raw1
   movwf   PORTA
   bsf      PORTA,4
   nop
   bcf      PORTA,4
   return

LCD_Cmd
   movwf   thebyte
   swapf   thebyte,w
   andlw   0fh
   iorwf   rwbyte,w
   call Raw1
   movf   thebyte,w
   andlw   0fh
   iorwf   rwbyte,w
   call Raw1
   DelayN 5
   return
   
   
; ##########################################################################   
LinearizeHumidity   
   movf   info1,w            ;x/128
   movwf   humip128
   rlf      info2,w
   rlf      humip128
   ;
   swapf   info1,w            ;x/32
   andlw   0f0h
   movwf   humip32
   swapf   info2,w
   andlw   0fh
   iorwf   humip32
   bcf      STATUS,C
   rrf      humip32
   ;
   movlw   4
   subwf   info1,w
   btfsc   STATUS,C
   goto   linh_f2
   movf   humip128,w         ; x<1024
   addlw   -3
   addwf   humip32
   movlw   200               ; do not go below 0
   subwf   humip32,w
   btfsc   STATUS,C
   clrf   humip32
   goto   linh_fe
linh_f2
   movlw   10
   subwf   info1,w
   btfsc   STATUS,C
   goto   linh_f3
   movf   humip32,w         ; 1024<=x<2560
   addlw   4
   movwf   humip32
   goto   linh_fe
linh_f3
   movf   humip128,w         ; 2560<=x
   addlw   -24
   subwf   humip32
linh_fe
   movf   humip32,w
   return


;##########################################################################   
BCD8_100   ;used to convert % Humidity
   ;input:  8 bit positive number [0..255]
   ;output: bcd100,bcd10,bcd1   (+leading spaces +saturate on 100)
   ;
   movwf   byte
   movlw   ' '
   movwf   bcd100         ; bcd100=' '
   clrf   bcd10
   decf   bcd10         ; bcd10 = -1
   movlw   '0'-1
   movwf   bcd1         ; bcd1  = '/'
   movlw   100
   subwf   byte,w
   btfsc   STATUS,C
   goto   bcd8_big100
   movlw   10            ;below 100
bcd8_big10               ;still >10
   subwf   byte         
   incf   bcd10
   btfsc   STATUS,C
   goto   bcd8_big10
      movlw   '0'
      btfsc   STATUS,Z   ;Z=1 if byte<10
      movlw   ' '
   addwf   bcd10
   movlw   11
   addwf   byte
   
bcd8_big1
   incf   bcd1
   decfsz   byte
   goto   bcd8_big1
   return
   
bcd8_big100
   movlw   '0'
   movwf   bcd100
   incf   bcd100
   movwf   bcd10
bcd8_end
   return

;########################################################################
;input:  temperature in (hi,lo)
;output: t100,t10,t1,t01   ( +leading spaces +[leading minus])
ComputeAsciiTemp
   dodigit   10000
   movwf   t100
   dodigit   1000
   movwf   t10
   dodigit   100
   movwf   t1
   dodigit   10
   movwf   t01
   ;"remove" zeroes
   BANKISEL 0
   movlw   t100
   movwf   FSR
   
   movlw   '0'
   xorwf   INDF,w
   skpz
   goto   ddrzend
   movlw   ' '
   movwf   t100

   incf   FSR
   movlw   '0'
   xorwf   INDF,w
   skpz
   goto   ddrztn
   movlw   ' '
   movwf   t10
   incf   FSR
ddrztn            ;test negative
   decfsz   negative
   goto   ddrzend
   decf   FSR
   movlw   '-'
   movwf   INDF
ddrzend   
   return         ; done

; "dosub" is called by the "dodigit" macro defined above.
; Subtract the number in shi/slo from hi/lo until the result
; is negative, incrementing the ascii equivelent each time.

dosub
   movlw   '0'-1
   movwf   digit
moresub   
   incf   digit,F      ; increment ASCII character
   call   Sub16      ; (hi,lo) - (shi,slo)
   btfsc   STATUS,C   ; any carry?
   goto   moresub      ; no, keep subtracting

   call   Add16      ; reverse the last subtraction
   movf   digit,W
   return

Sub16
   movf   slo,w      ; subtract current power of 10
   subwf   lo,f      ; lo = lo - slo
   movf   shi,w
   btfss   STATUS,C
   addlw   1
   subwf   hi,f      ; hi = hi - shi - NC
   return

Add16
   movf   slo,w      
   addwf   lo,f
   movf   shi,w
   btfsc   STATUS,C
   addlw   1
   addwf   hi,f
   return
   
;###########################################################################
; prepare the text: Temp:000.0^C__Humi:000%
InitTXT
   movlw 'T'
   movwf txtTemp
   movlw 'e'
   movwf txtTemp+1
   movlw 'm'
   movwf txtTemp+2
   movlw 'p'
   movwf txtTemp+3
   movlw ':'
   movwf txtTemp+4
   movlw '.'
   movwf tdot

   
   movlw 0xdf
   movwf txtHumi
   movlw 'C'
   movwf txtHumi+1
   movlw ' '
   movwf txtHumi+2
   movlw ' '
   movwf txtHumi+3
   movlw 'H'
   movwf txtHumi+4
   movlw 'u'
   movwf txtHumi+5
   movlw 'm'
   movwf txtHumi+6
   movlw 'i'
   movwf txtHumi+7
   movlw ':'
   movwf txtHumi+8
   movlw '%'
   movwf txtDewP
   return
;###########################################################################
; text on error: Temp:000.0^C__Humi:000%
ErrTXT
   movlw ' '
   movwf t100
   movwf t10
   movwf t01
   movwf bcd100
   movwf bcd1
   movlw '?'
   movwf t1
   movwf bcd10
   return
;###########################################################################
DelayMs            ;ms
   ;movlw 10      ;in W (sau cnt1) parametru intirzierea 1..255
   movwf cnt1      ;incarc pe cnt1 din delval din prog Pp
delaymsjcnt1
   movlw d'7'
   movwf cnt2
delaymsjcnt2
   movlw d'236'
   movwf cnt3
delaymsjcnt3
   decfsz cnt3
   goto delaymsjcnt3
   decfsz cnt2
   goto delaymsjcnt2
   decfsz cnt1
   goto delaymsjcnt1
   return
   
           END

'******************************************

XNHCX

[elektromer]

Tüm arkadaşlara Merhaba,

Teşekkürler XNHCX   SHT11 Kodlari için.

Eğer yüzsüzlük olmaz ise HEX dosyasınıda alabilirmiyim.


Saygılarımla...

[XNHCX]

******************Sht11lcd.hex*********************

:10000000830100308A000428850183160A30990094
:100010002430980006309F008501FC30870087114E
:1000200083129030980007108710AE01E720A221BC
:1000300005305B20003E031D59281821A6003D21F4
:1000400003305B20003E031D59282708C8002808FC
:10005000C9000F30CA00A030CB00CD019421031895
:1000600039280030CA000130CB009421C809C909E1
:10007000CD0A5C2102300C21AD160C30AA003030C4
:100080008400840A00080C21AA0B4128AD01C0306D
:100090000C21AD160930AA003E308400840A000805
:1000A0000C21AA0B4E28AD010030CD210030CD210E
:1000B0001828C3213A28A60083160712831282202B
:1000C00061282E08A5002608C5208A2003187A2852
:1000D000B420013A03197C289F20A700C5209F2047
:1000E000A800C5209F202608A900D420A506031D2E
:1000F0007E280034FD308028FE308028FF308028A4
:10010000DD20FF340716871507128711871507169C
:10011000871108000830AA008711A60D031C0712DA
:10012000031807168715AA0B8C2887118316071644
:10013000831287150310071A03148711080008306B
:10014000AA0087150310071A0314A60D8711AA0B1E
:10015000A1288316071283120712871587118316A9
:1001600007168312260808000430A000A101A2018E
:10017000071E0034A20BB828A10BB728A00BB62885
:1001800001340C1EC12899000800A3000830AA0001
:1001900023082506A400A40D18300318A506A50DF4
:1001A000A30DAA0BC8280800A4000830AA00A40DBB
:1001B000A30CAA0BD72823080800071687110930BB
:1001C000AA0087158711AA0BE12882200800323087
:1001D000CD21AD01033007210530CD2103300721AA
:1001E0000130CD21033007210130CD21023007211C
:1001F0000130CD2128300C2108300C2101300C2198
:100200000C300C2106300C210A30CD21080085006D
:100210000516000005120800AC002C0E0F392D0445
:1002200007212C080F392D0407210530CD210800A6
:100230002708AF00280DAF0D270EF039B000280EAB
:100240000F39B0040310B00C043027020318302912
:100250002F08FD3EB007C83030020318B0013B291B
:100260000A302702031838293008043EB0003B2921
:100270002F08E83EB00230080800A6002030C40075
:10028000C501C5032F30C600643026020318572964
:100290000A30A602C50A0318492930300319203054
:1002A000C5070B30A607C60AA60B53290800303035
:1002B000C400C40AC50008002730CA001030CB00B3
:1002C0008B21B6000330CA00E830CB008B21B70089
:1002D0000030CA006430CB008B21B8000030CA0067
:1002E0000A30CB008B21BA008313363084003030C3
:1002F0000006031D8A292030B600840A303000062B
:10030000031D85292030B700840ACD0B8A29840378
:100310002D30800008002F30CC00CC0A9421031827
:100320008D299B214C0808004B08C9024A08031C70
:10033000013EC80208004B08C9074A080318013EDD
:10034000C80708005430B1006530B2006D30B3000A
:100350007030B4003A30B5002E30B900DF30BB0049
:100360004330BC002030BD002030BE004830BF000C
:100370007530C0006D30C1006930C2003A30C30032
:100380002530C70008002030B600B700BA00C4000E
:10039000C6003F30B800C5000800A0000730A1002B
:1003A000EC30A200A20BD229A10BD029A00BCE29A0
:0203B000080043
:02400E00721F1F
:00000001FF

**************************************************
XNHCX

[elektromer]

Merhaba,

Hızlı servis için çok teşekkür XNHCX ederim..

Herşey gönlünüzce olsun...